SUBROUTINE READDATA(LU,U,V,W,DBZ,IMAX,JMAX,KMAX,FLTNAME,
     1 IHS,IMS,ISS,IHE,IME,ISE,SLAT,SLON,ROT,SX,SY,SZ,
     1 XZ,YZ,ZZ)
      CHARACTER FLTNAME*6
C U--EAST WEST COMPONENT OF WIND IN M/S
C V--NORTH SOUTH COMPONENT OF WIND IN M/S
C W--VERTICAL COMPONENT OF WIND IN M/S
C DBZ--RADAR REFLECTIVITY IN DBZ
C
C
C THE DIMENSIONS OF U,V,W,AND DBZ ALLOW UP TO ONE MILLION GRID POINTS
C IN ANY COMBINATION OF DOMAINS IN X, Y, AND Z
C YOU WILL HAVE TO SEND THESE TO THE MAIN PROGRAM AND THEN OUT TO
C ANOTHER SUBROUTINE WITH U,V,W,AND DBZ DIMENSIONED AS 
C REAL U(IMAX,JMAX,KMAX)....ETC.
C
C
      REAL U(1000000),V(1000000)
      REAL W(1000000),DBZ(1000000)
C
C LU--LOGICAL UNIT NUMBER FOR THE WIND ASCII FILE 
C YOU SHOULD ALREADY HAVE OPENED THE LU FILE AS FORMATTED SEQUENTIAL
C
C FLTNAM IS IN THE FORM YYMMDD
C
      READ(LU,'(A6)')FLTNAME
C
C IHS,IMS,ISS ARE THE HOURS MINUTES AND SECONDS IN UTC FOR START OF DATA
C
      READ(LU,91)IHS,IMS,ISS,IHE,IME,ISE
91    FORMAT(3I2,X,3I2)
C
C IHE,IME,ISE ARE THE HOURS MINUTES AND SECONDS IN UTC FOR END OF DATA
C
      WRITE(6,91)IHS,IMS,ISS,IHE,IME,ISE
C
C SLAT AND SLON ARE THE LOCATION OF STORM CENTER, WHICH IS PLACED AT
C THE CENTER OF THE ANALYSIS
C
C ROT IS THE ACTUAL AZIUMTH OF THE POSITIVE Y AXIS.  THIS IS NORMALLY 0.
C 
      READ(LU,92)SLAT,SLON,ROT
92    FORMAT(3F10.3)
93    FORMAT(3F6.2)
94    FORMAT(3I4)
C
C SX,SY,SZ ARE RESOLUTIONS IN THE X, Y, AND Z DIRECTIONS IN KM
C
      READ(LU,93)SX,SY,SZ
C
C XZ IS THE X DISTANCE IN KM OF STORM CENTER FROM 
C LOWER LEFT CORNER OF LOWER LEFT GRID CELL AND THUS
C X RELATIVE TO STORM CENTER IS (I-1)*SX +.5*SX - XZ
C YZ IS ANALAGOUS FOR THE Y COORDINATE WHERE 
C Y RELATIVE TO STORM CENTER IS (J-1)*SY +.5*SY - YZ
C Z (HEIGHT) IS ZZ +(K-1)*SZ
C FOR ABOVE THIS IS BASED ON U(I,J,K)
C
      READ(LU,93)XZ,YZ,ZZ
C
C IMAX, JMAX, AND KMAX ARE THE NUMBER OF GRID POINTS IN THE X, Y AND VERTICAL
C DIRECTIONS
C
      READ(LU,94)IMAX,JMAX,KMAX
      CALL READWIND(LU,U,V,W,DBZ,IMAX,JMAX,KMAX)
      RETURN
      END
      SUBROUTINE READWIND(LU,U,V,W,DBZ,IMAX,JMAX,KMAX)
      REAL U(IMAX,JMAX,KMAX),V(IMAX,JMAX,KMAX)
      REAL W(IMAX,JMAX,KMAX),DBZ(IMAX,JMAX,KMAX)
      DO K=1,KMAX
       DO J=1,JMAX
        READ(LU,10)(DBZ(I,J,K),I=1,IMAX)
       ENDDO
       DO J=1,JMAX
        READ(LU,10)(U(I,J,K),I=1,IMAX)
       ENDDO
       DO J=1,JMAX
        READ(LU,10)(V(I,J,K),I=1,IMAX)
       ENDDO
       DO J=1,JMAX
        READ(LU,10)(W(I,J,K),I=1,IMAX)
       ENDDO
      ENDDO
10    FORMAT(10F7.1)
      RETURN
      END