SUBROUTINE READRADIALS(LU,ICALLED,IYEAR,IMONTH,IDAY,MAXI,
     1 RADIUS,TIMERAD,RRLAT,RRLON,RRA,EAZM,EEV,VR,IEOF)
C SUBROUTINE READRADIALS reads quality controlled ascii radial data from
C HRD website and provides it to the calling subroutine
C Radial Velocities are earth relative.  The projection of 
C aircraft motion has been subtracted but not storm motion.
C
C LU is the logical unit number of Doppler radial file, which should already
C be opened as sequential formatted (default) before the first call to this
C routine
C
C ICALLED should be set to zero before the first call to READRADIALS
C
C IYEAR IS YEAR-2000
C
C IMONTH IS NUMERICAL MONTH OF YEAR e.g IMONTH=8 is August
C
C IDAY is day of the month
C
C MAXI NUMBER OF RADIAL BINS OF DATA
C
C TIMERAD is time in seconds after midnight based upon day that flight began
C
C RRLAT is latitude of aircraft in degrees
C
C RRLON is longitue of aircraft in degrees, West longitude being negative
C
C RRA is the aicraft (radar) altitude in meters
C
C EAZM is the earth relative aziumth,defined as eastward being zero and 
C angle value increasing counterclockwise (in other words this is a geometric
C angle rather than a navigational angle) e.g. northward=90
C westward=180 (or -180) and southward=270 (or -90) 
C
C EEV is the earth relative elevation angle where -90 equals pointing toward
C nadir, 0 is horizontal and 90 means pointing toward zenith
C
C RADIUS is the distance from aircraft in km
C
C VR is the quality-controlled Doppler radial 
C velocity, defined positive outwards
C
      REAL RADIUS (512),VR(512)
C Routine returns IEOF of 0 if a new radial has been read
C and IEOF of 1 if at end of file
C
      IEOF=0
 1    IF(ICALLED.EQ.0)THEN
       READ(LU,'(3I2,X,I3)')IYEAR,IMONTH,IDAY,MAXI
       READ(LU,'(8F10.3)')(RADIUS(I),I=1,MAXI)
       ICALLED=1
      ENDIF
      READ(LU,'(8F10.3)',END=999)TIMERAD,RRLAT,RRLON,RRA,EAZM,EEV,
     1 (VR(I),I=1,MAXI)
      IF(TMSWEEP.LT.0.)THEN
       READ(LU,'(I3)')MAXI
       READ(LU,'(8F10.3)')(RADIUS(I),I=1,MAXI)
       READ(LU,'(8F10.3)')TIMERAD,RRLAT,RRLON,RRA,EAZM,EEV,
     1 (VR(I),I=1,MAXI)
      ENDIF
      RETURN
 999  IEOF=1
      RETURN
      END